PBMiner

$PBExportHeader$eaf_n_cst_conversionservice.sru
forward
global type eaf_n_cst_conversionservice from n_cst_baseservice
end type
end forward

global type eaf_n_cst_conversionservice from n_cst_baseservice
end type
global eaf_n_cst_conversionservice eaf_n_cst_conversionservice

type variables
Protected:

boolean                 ib_enumeratedexclamation = true
string                  is_enumeratedexclamation = '!'


end variables

forward prototypes
public function boolean boolean (string as_value)
public function long dwbuffer (string as_dwbuffer, ref dwbuffer ae_dwbuffer)
public function long dwitemstatus (string as_dwitemstatus, ref dwitemstatus ae_dwitemstatus)
public function long location (string as_location, ref location ae_location)
public function long numeric (boolean ab_boolean)
public function long ostype (string as_ostype, ref ostypes ae_ostype)
public function long setenumeratedexclamation (boolean ab_useexclamation)
public function long sqlpreviewfunction (string as_sqlpreviewfunction, ref sqlpreviewfunction ae_sqlpreviewfunction)
public function long sqlpreviewtype (string as_sqlpreviewtype, ref sqlpreviewtype ae_sqlpreviewtype)
public function string string (dwbuffer ae_dwbuffer)
public function string string (dwitemstatus ae_dwitemstatus)
public function string string (sqlpreviewtype ae_sqlpreviewtype)
public function boolean isenumeratedexclamation ()
public function boolean boolean (long al_numeric)
public function string string (ostypes ae_ostype)
public function string string (location ae_location)
public function string string (sqlpreviewfunction ae_sqlpreviewfunction)
end prototypes

public function boolean boolean (string as_value);////////////////////////////////////////////////////////////////
// Description:
//    Converts many possible text representations to a boolean
// Revisions
//    1.0   - Initial version
// Arguments:  
//    as_value - The value to be converted
// Returns:
//    True if one of the "true" representations
//    False otherwise
////////////////////////////////////////////////////////////////
// Copyright © 2000 - 2007 Youngsoft, Inc.  All rights reserved.
// Any distribution of the Youngsoft, Inc. Enterprise Application Framework
// source code in whole or part by other than Youngsoft, Inc. is prohibited.
//////////////////////////////////////////////////////////////// 

constant string METHOD_NAME = "boolean "

If ib_trace Then
   inv_log.traceLog (METHOD_NAME,  "(as_value)   as_value="+string(as_value))
End If   

// Perform cleanup
as_value = trim(lower(as_value))

// Validate arguments
If isNull(as_value) Or len(as_value) = 0 Then
   addError (METHOD_NAME,  "Invalid as_value argument")
   Return false
End If

// These are the "text" representations for True
Choose Case as_value
   Case "1", "true", "t", "yes", "y", "on" 
      Return True
End Choose

Return false

end function

public function long dwbuffer (string as_dwbuffer, ref dwbuffer ae_dwbuffer);////////////////////////////////////////////////////////////////
// Description:
//    Converts a string representation of dwBuffer to the
//    appropriate Enumerated dwBuffer
// Revisions
//    1.0   - Initial version
// Arguments:  
//    as_dwbuffer - The value to be converted
//    ae_dwbuffer - Place holder for the converted value
// Returns:
//     1 - Success
//    -1 - Failure
////////////////////////////////////////////////////////////////
// Copyright © 2000 - 2007 Youngsoft, Inc.  All rights reserved.
// Any distribution of the Youngsoft, Inc. Enterprise Application Framework
// source code in whole or part by other than Youngsoft, Inc. is prohibited.
//////////////////////////////////////////////////////////////// 

constant string METHOD_NAME = "dwBuffer "

If ib_trace Then
   inv_log.traceLog (METHOD_NAME,  "(as_dwbuffer, ref ae_dwbuffer)   " + &
      "as_dwbuffer="+as_dwbuffer)
End If   

// Perform cleanup
as_dwbuffer = trim(lower(as_dwbuffer))

// Validate arguments
If isNull(as_dwbuffer) Or len(as_dwbuffer) = 0 Then
   addError (METHOD_NAME,  "Invalid as_dwbuffer argument")
   Return -1
End If

// Perform the actual conversion
Choose Case as_dwbuffer
   Case "primary!", "primary"
      ae_dwbuffer = primary!
   Case "filter!", "filter"
      ae_dwbuffer = filter!
   Case "delete!", "delete"
      ae_dwbuffer = delete!
   Case Else
      // Unrecognized
      Return -1
End Choose

Return 1
end function

public function long dwitemstatus (string as_dwitemstatus, ref dwitemstatus ae_dwitemstatus);////////////////////////////////////////////////////////////////
// Description:
//    Converts a string representation of dwItemStatus to the
//    appropriate enumerated dwItemStatus
// Revisions
//    1.0   - Initial version
// Arguments:  
//    as_dwitemstatus - The value to be converted
//    ae_dwitemstatus - Place holder for the converted value
// Returns:
//     1 - Success
//    -1 - Failure
////////////////////////////////////////////////////////////////
// Copyright © 2000 - 2007 Youngsoft, Inc.  All rights reserved.
// Any distribution of the Youngsoft, Inc. Enterprise Application Framework
// source code in whole or part by other than Youngsoft, Inc. is prohibited.
//////////////////////////////////////////////////////////////// 

constant string METHOD_NAME = "dwItemStatus "

If ib_trace Then
   inv_log.traceLog (METHOD_NAME,  "(as_dwitemstatus, ref ae_dwitemstatus)   " + &
      "as_dwitemstatus="+as_dwitemstatus)
End If   

// Perform cleanup
as_dwitemstatus = trim(lower(as_dwitemstatus))

// Validate arguments
If isNull(as_dwitemstatus) Or len(as_dwitemstatus) = 0 Then
   addError (METHOD_NAME,  "Invalid as_dwitemstatus argument")
   Return -1
End If

// Perform the actual conversion
Choose Case as_dwitemstatus
   Case "new!", "new"
      ae_dwItemStatus = new!
   Case "newmodified!", "newmodified"
      ae_dwItemStatus = newModified!
   Case "notmodified!", "notmodified"
      ae_dwItemStatus = notModified!
   Case "datamodified!", "datamodified"
      ae_dwItemStatus = dataModified!
   Case Else
      // Unrecognized
      Return -1
End Choose

Return 1
end function

public function long location (string as_location, ref location ae_location);////////////////////////////////////////////////////////////////
// Description:
//    Converts a string representation of the Location system type
//    to the enumerated version
// Revisions
//    1.0   - Initial version
// Arguments:  
//    as_location    - The value to be converted
//    ae_location    - Place holder for the converted value
// Returns:
//     1 - Success 
//    -1 - Failure
////////////////////////////////////////////////////////////////
// Copyright © 2000 - 2007 Youngsoft, Inc.  All rights reserved.
// Any distribution of the Youngsoft, Inc. Enterprise Application Framework
// source code in whole or part by other than Youngsoft, Inc. is prohibited.
//////////////////////////////////////////////////////////////// 

constant string METHOD_NAME = "location "

If ib_trace Then
   inv_log.traceLog (METHOD_NAME,  "(as_location, ref ae_location)   " + &
      "as_location="+as_location)
End If

// Perform cleanup
as_location = trim(lower(as_location))

// Validate arguments
If isNull(as_location) or len(as_location) = 0 Then
   addError (METHOD_NAME,  "Invalid as_location argument")
   Return -1
End If

// Perform the actual conversion
Choose Case as_location
   Case "first!", "first"
      ae_location = first!    
   Case "next!", "next"
      ae_location = next!     
   Case "prior!", "prior"
      ae_location = prior!
   Case "last!", "last"
      ae_location = last!
   Case Else
      // Unrecognized value
      Return -1
End Choose

Return 1
end function

public function long numeric (boolean ab_boolean);////////////////////////////////////////////////////////////////
// Description:
//    Converts a boolean value to a numeric representation
// Revisions
//    1.0   - Initial version
// Arguments:  
//    ab_boolean - The value to be converted
// Returns:
//     1 - Success - boolean was True value
//     0 - Success - boolean was False value
//    -1 - Failure
////////////////////////////////////////////////////////////////
// Copyright © 2000 - 2007 Youngsoft, Inc.  All rights reserved.
// Any distribution of the Youngsoft, Inc. Enterprise Application Framework
// source code in whole or part by other than Youngsoft, Inc. is prohibited.
//////////////////////////////////////////////////////////////// 

constant string METHOD_NAME = "numeric "

If ib_trace Then
   inv_log.traceLog (METHOD_NAME,  "(ab_boolean)   ab_boolean="+string(ab_boolean))
End If   

// Validate arguments
If isNull(ab_boolean) Then
   addError (METHOD_NAME,  "Invalid ab_boolean argument")
   Return -1
End If

// Perform the actual conversion
If ab_boolean Then
   Return 1
End If

Return 0

end function

public function long ostype (string as_ostype, ref ostypes ae_ostype);////////////////////////////////////////////////////////////////
// Description:
//    Converts a string representation of the operating system type
//    to the enumerated version
// Revisions
//    1.0   - Initial version
// Arguments:  
//    as_ostype   - The value to be converted
//    ae_ostype   - Place holder for the converted value
// Returns:
//     1 - Success 
//    -1 - Failure
////////////////////////////////////////////////////////////////
// Copyright © 2000 - 2007 Youngsoft, Inc.  All rights reserved.
// Any distribution of the Youngsoft, Inc. Enterprise Application Framework
// source code in whole or part by other than Youngsoft, Inc. is prohibited.
//////////////////////////////////////////////////////////////// 

constant string METHOD_NAME = "osType "

If ib_trace Then
   inv_log.traceLog (METHOD_NAME,  "(as_ostype, ref ae_ostype)   as_ostype="+as_ostype)
End If

// Perform cleanup
as_ostype = trim(lower(as_ostype))

// Validate arguments
If isNull(as_ostype) or len(as_ostype) = 0 Then
   addError (METHOD_NAME,  "Invalid as_ostype argument")
   Return -1
End If

// Perform the actual conversion
Choose Case as_ostype
   Case "windowsnt!", "windowsnt"
      ae_ostype = WINDOWSNT!     
   Case "sol2!", "sol2"
      ae_ostype = SOL2!    
   Case "aix!", "aix"
      ae_ostype = AIX!
   Case "hpux!", "hpux"
      ae_ostype = HPUX!
   Case "osf1!", "osf1"
      ae_ostype = OSF1!
   Case "windows!", "windows"
      ae_ostype = WINDOWS!
   Case "macintosh!", "macintosh"
      // No longer supported by PB as of version 7
      ae_ostype = MACINTOSH!     
   Case Else
      // Unrecognized value
      Return -1
End Choose

Return 1
end function

public function long setenumeratedexclamation (boolean ab_useexclamation);////////////////////////////////////////////////////////////////
// Description:
//    Tells the service if string representations of Enumerated
//    values should have the Exclamation or Not.
// Revisions
//    1.0   - Initial version
// Arguments:  
//    ab_useexclamation - True means to have the exclamation
// Returns:
//     1 - Success
//    -1 - Failure
////////////////////////////////////////////////////////////////
// Copyright © 2000 - 2007 Youngsoft, Inc.  All rights reserved.
// Any distribution of the Youngsoft, Inc. Enterprise Application Framework
// source code in whole or part by other than Youngsoft, Inc. is prohibited.
//////////////////////////////////////////////////////////////// 

constant string METHOD_NAME = "setEnumeratedExclamation "

If ib_trace Then
   inv_log.traceLog (METHOD_NAME,  "(ae_dwbuffer)")
End If   

// Validate arguments
If isNull(ab_useexclamation) Then
   addError (METHOD_NAME,  "Invalid ab_useexclamation argument")

   Return -1
End If

// Set the attribute and its interpreted value
ib_enumeratedexclamation = ab_useexclamation
If ib_enumeratedexclamation Then
   is_enumeratedexclamation = "!"
Else
   is_enumeratedexclamation = ""
End If

Return 1
end function

public function long sqlpreviewfunction (string as_sqlpreviewfunction, ref sqlpreviewfunction ae_sqlpreviewfunction);////////////////////////////////////////////////////////////////
// Description:
//    Converts a string representation of the sqlPreviewFunction system type
//    to the enumerated version
// Revisions
//    1.0   - Initial version
// Arguments:  
//    as_sqlPreviewFunction - The value to be converted
//    ae_sqlPreviewFunction - Place holder for the converted value
// Returns:
//     1 - Success 
//    -1 - Failure
////////////////////////////////////////////////////////////////
// Copyright © 2000 - 2007 Youngsoft, Inc.  All rights reserved.
// Any distribution of the Youngsoft, Inc. Enterprise Application Framework
// source code in whole or part by other than Youngsoft, Inc. is prohibited.
//////////////////////////////////////////////////////////////// 

constant string METHOD_NAME = "sqlPreviewFunction "

If ib_trace Then
   inv_log.traceLog (METHOD_NAME,  "(as_sqlpreviewfunction, ref ae_as_sqlpreviewfunction)   " + &
      "as_sqlpreviewfunction="+as_sqlpreviewfunction)
End If

// Perform cleanup
as_sqlpreviewfunction = trim(lower(as_sqlpreviewfunction))

// Validate arguments
If isNull(as_sqlpreviewfunction) or len(as_sqlpreviewfunction) = 0 Then
   addError (METHOD_NAME,  "Invalid as_sqlpreviewfunction argument")
   Return -1
End If

// Perform the actual conversion
Choose Case as_sqlpreviewfunction
   Case "previewfunctionretrieve!", "previewfunctionretrieve"
      ae_sqlpreviewfunction = previewFunctionRetrieve!      
   Case "previewfunctionreselectrow!", "previewfunctionreselectrow"
      ae_sqlpreviewfunction = previewFunctionReselectRow!      
   Case "previewfunctionupdate!", "previewfunctionupdate"
      ae_sqlpreviewfunction = previewFunctionUpdate!
   Case Else
      // Unrecognized value
      Return -1
End Choose

Return 1
end function

public function long sqlpreviewtype (string as_sqlpreviewtype, ref sqlpreviewtype ae_sqlpreviewtype);////////////////////////////////////////////////////////////////
// Description:
//    Converts a string representation of the sqlPreviewType system type
//    to the enumerated version
// Revisions
//    1.0   - Initial version
// Arguments:  
//    as_sqlpreviewtype - The value to be converted
//    ae_sqlpreviewtype - Place holder for the converted value
// Returns:
//     1 - Success 
//    -1 - Failure
////////////////////////////////////////////////////////////////
// Copyright © 2000 - 2007 Youngsoft, Inc.  All rights reserved.
// Any distribution of the Youngsoft, Inc. Enterprise Application Framework
// source code in whole or part by other than Youngsoft, Inc. is prohibited.
//////////////////////////////////////////////////////////////// 

constant string METHOD_NAME = "sqlPreviewType "

If ib_trace Then
   inv_log.traceLog (METHOD_NAME,  "(as_sqlpreviewtype, ref ae_sqlpreviewtype)   " + &
      "as_sqlpreviewtype="+as_sqlpreviewtype)
End If

// Perform cleanup
as_sqlpreviewtype = trim(lower(as_sqlpreviewtype))

// Validate arguments
If isNull(as_sqlpreviewtype) or len(as_sqlpreviewtype) = 0 Then
   addError (METHOD_NAME,  "Invalid as_sqlpreviewtype argument")
   Return -1
End If

// Perform the actual conversion
Choose Case as_sqlpreviewtype
   Case "previewselect!", "previewselect"
      ae_sqlpreviewtype = PreviewSelect!     
   Case "previewinsert!", "previewinsert"
      ae_sqlpreviewtype = PreviewInsert!     
   Case "previewupdate!", "previewupdate"
      ae_sqlpreviewtype = PreviewUpdate!
   Case "previewdelete!", "previewdelete"
      ae_sqlpreviewtype = PreviewDelete!     
   Case Else
      // Unrecognized value
      Return -1
End Choose

Return 1
end function

public function string string (dwbuffer ae_dwbuffer);////////////////////////////////////////////////////////////////
// Description:
//    Converts the Enumerated dwBuffer value to a string
// Revisions
//    1.0   - Initial version
// Arguments:  
//    ae_dwbuffer - The value to be converted
// Returns:
//    The string representation
//    "!" - Failure
////////////////////////////////////////////////////////////////
// Copyright © 2000 - 2007 Youngsoft, Inc.  All rights reserved.
// Any distribution of the Youngsoft, Inc. Enterprise Application Framework
// source code in whole or part by other than Youngsoft, Inc. is prohibited.
//////////////////////////////////////////////////////////////// 

constant string METHOD_NAME = "string ( dwbuffer )"

inv_log.traceLog (METHOD_NAME,  "(ae_dwbuffer)")

// Validate arguments
If isNull(ae_dwbuffer) Then
   addError (METHOD_NAME,  "Invalid ae_dwbuffer argument")
   Return "!"
End If

// Perform the actual conversion
Choose Case ae_dwbuffer
   Case primary!
      Return 'primary' + is_enumeratedexclamation
   Case filter!
      Return 'filter' + is_enumeratedexclamation
   Case delete!
      Return 'delete' + is_enumeratedexclamation
End Choose

Return '!'
end function

public function string string (dwitemstatus ae_dwitemstatus);////////////////////////////////////////////////////////////////
// Description:
//    Converts the Enumerated dwItemStatus value to a string
//    Revisions
//    1.0   - Initial version
// Arguments:  
//    ae_dwitemstatus - The value to be converted
// Returns:
//    The string representation
//    "!" - Failure
////////////////////////////////////////////////////////////////
// Copyright © 2000 - 2007 Youngsoft, Inc.  All rights reserved.
// Any distribution of the Youngsoft, Inc. Enterprise Application Framework
// source code in whole or part by other than Youngsoft, Inc. is prohibited.
//////////////////////////////////////////////////////////////// 

constant string METHOD_NAME = "string ( dwitemstatus )"

inv_log.traceLog (METHOD_NAME,  "")

// Validate arguments
If isNull(ae_dwitemstatus) Then
   addError (METHOD_NAME,  "Invalid ae_dwitemstatus argument")
   Return "!"
End If

// Perform the actual conversion
Choose Case ae_dwitemstatus
   Case new!
      Return 'new' + is_enumeratedexclamation
   Case newModified!
      Return 'newModified' + is_enumeratedexclamation    
   Case notModified!
      Return 'notModified' + is_enumeratedexclamation
   Case dataModified!
      Return 'dataModified' + is_enumeratedexclamation
End Choose

Return '!'
end function

public function string string (sqlpreviewtype ae_sqlpreviewtype);////////////////////////////////////////////////////////////////
// Description:
//    Converts the Enumerated sqlPreviewType value to a stri// Revisionsnge)
//    1.0   - Initial version
// Arguments:  
//    ae_sqlpreviewtype - The value to be converted
// Returns:
//    The string representation
//    "!" - Failure
////////////////////////////////////////////////////////////////
// Copyright © 2000 - 2007 Youngsoft, Inc.  All rights reserved.
// Any distribution of the Youngsoft, Inc. Enterprise Application Framework
// source code in whole or part by other than Youngsoft, Inc. is prohibited.
//////////////////////////////////////////////////////////////// 

constant string METHOD_NAME = "string ( sqlpreviewtype )"

inv_log.traceLog (METHOD_NAME,  "")

// Validate arguments
If isNull(ae_sqlpreviewtype) Then
   addError (METHOD_NAME,  "Invalid ae_sqlpreviewtype argument")
   Return "!"
End If

// Perform the actual conversion
Choose Case ae_sqlpreviewtype
   Case previewSelect!
      Return 'previewSelect' + is_enumeratedexclamation           
   Case previewInsert!
      Return 'previewInsert' + is_enumeratedexclamation        
   Case previewUpdate!
      Return 'previewUpdate' + is_enumeratedexclamation     
   Case previewDelete!
      Return 'previewDelete' + is_enumeratedexclamation     
End Choose

Return '!'
end function

public function boolean isenumeratedexclamation ();////////////////////////////////////////////////////////////////
// Description:
//    Reports if the service will/is putting Exclamation at the
///   end of string representations of Enumerated va// Revisionshange)
//    1.0   - Initial version
// Arguments:  
//    None
// Returns:
//    True if they are being put on
//    False otherwise
////////////////////////////////////////////////////////////////
// Copyright © 2000 - 2007 Youngsoft, Inc.  All rights reserved.
// Any distribution of the Youngsoft, Inc. Enterprise Application Framework
// source code in whole or part by other than Youngsoft, Inc. is prohibited.
//////////////////////////////////////////////////////////////// 

constant string METHOD_NAME = "isEnumeratedExclamation "

Return ib_enumeratedexclamation
end function

public function boolean boolean (long al_numeric);////////////////////////////////////////////////////////////////
// Description:
//    Converts a numeric value to a boo// Revisionshange)
//    1.0   - Initial version
// Arguments:  
//    al_numeric - The value to be converted
// Returns:
//    True if the number equals 1 
//    False otherwise
////////////////////////////////////////////////////////////////
// Copyright © 2000 - 2007 Youngsoft, Inc.  All rights reserved.
// Any distribution of the Youngsoft, Inc. Enterprise Application Framework
// source code in whole or part by other than Youngsoft, Inc. is prohibited.
//////////////////////////////////////////////////////////////// 

constant string METHOD_NAME = "boolean "

If ib_trace Then
   inv_log.traceLog (METHOD_NAME,  "(al_numeric)   al_numeric="+string(al_numeric))
End If   

// Validate arguments
If IsNull(al_numeric) Then
   addError (METHOD_NAME,  "Invalid al_numeric argument")
   Return false
End If

// The only TRUE condition is if the value equals 1
If al_numeric = 1 Then
   Return true
End If

Return false
end function

public function string string (ostypes ae_ostype);////////////////////////////////////////////////////////////////
// Description:
//    Converts the Enumerated osType value to a st// Revisionshange)
//    1.0   - Initial version
// Arguments:  
//    ae_ostype - The value to be converted
// Returns:
//    The string representation
//    "!" - Failure
////////////////////////////////////////////////////////////////
// Copyright © 2000 - 2007 Youngsoft, Inc.  All rights reserved.
// Any distribution of the Youngsoft, Inc. Enterprise Application Framework
// source code in whole or part by other than Youngsoft, Inc. is prohibited.
//////////////////////////////////////////////////////////////// 

constant string METHOD_NAME = "string ( ostypes )"

inv_log.traceLog (METHOD_NAME,  "")

// Validate arguments
If isNull(ae_ostype) Then
   addError (METHOD_NAME,  "Invalid ae_ostype argument")
   Return "!"
End If

// Perform the actual conversion
Choose Case ae_ostype
   Case windowsNT!
      Return 'windowsNT' + is_enumeratedexclamation         
   Case sol2!
      Return 'sol2' + is_enumeratedexclamation     
   Case aix!
      Return 'aix' + is_enumeratedexclamation
   Case hpux!
      Return 'hpux' + is_enumeratedexclamation     
   Case osf1!
      Return 'osf1' + is_enumeratedexclamation
   Case windows!
      Return 'windows' + is_enumeratedexclamation
   Case macintosh!
      // No longer supported by PB as of version 7    
      Return 'macintosh' + is_enumeratedexclamation      
End Choose

Return '!'
end function

public function string string (location ae_location);////////////////////////////////////////////////////////////////
// Description:
//    Converts the Enumerated location value to a // Revisions change)
//    1.0   - Initial version
// Arguments:  
//    ae_location - The value to be converted
// Returns:
//    The string representation
//    "!" - Failure
////////////////////////////////////////////////////////////////
// Copyright © 2000 - 2007 Youngsoft, Inc.  All rights reserved.
// Any distribution of the Youngsoft, Inc. Enterprise Application Framework
// source code in whole or part by other than Youngsoft, Inc. is prohibited.
//////////////////////////////////////////////////////////////// 

constant string METHOD_NAME = "string ( location )"

inv_log.traceLog (METHOD_NAME,  "")

// Validate arguments
If isNull(ae_location) Then
   addError (METHOD_NAME,  "Invalid ae_location argument")
   Return "!"
End If

// Perform the actual conversion
Choose Case ae_location
   Case first!
      Return 'first' + is_enumeratedexclamation       
   Case next!
      Return 'next' + is_enumeratedexclamation     
   Case prior!
      Return 'prior' + is_enumeratedexclamation
   Case last!
      Return 'last' + is_enumeratedexclamation     
End Choose

Return '!'
end function

public function string string (sqlpreviewfunction ae_sqlpreviewfunction);////////////////////////////////////////////////////////////////
// Description:
//    Converts the Enumerated sqlPreviewFunction value to // Revisionson change)
//    1.0   - Initial version
// Arguments:  
//    ae_sqlpreviewfunction - The value to be converted
// Returns:
//    The string representation
//    "!" - Failure
////////////////////////////////////////////////////////////////
// Copyright © 2000 - 2007 Youngsoft, Inc.  All rights reserved.
// Any distribution of the Youngsoft, Inc. Enterprise Application Framework
// source code in whole or part by other than Youngsoft, Inc. is prohibited.
//////////////////////////////////////////////////////////////// 

constant string METHOD_NAME = "string ( sqlpreviewfunction )"

inv_log.traceLog (METHOD_NAME,  "")

// Validate arguments
If isNull(ae_sqlpreviewfunction) Then
   addError (METHOD_NAME,  "Invalid ae_sqlpreviewfunction argument")
   Return "!"
End If

// Perform the actual conversion
Choose Case ae_sqlpreviewfunction
   Case previewFunctionRetrieve!
      Return 'previewFunctionRetrieve' + is_enumeratedexclamation       
   Case previewFunctionReselectRow!
      Return 'previewFunctionReselectRow' + is_enumeratedexclamation    
   Case previewFunctionUpdate!
      Return 'previewFunctionUpdate' + is_enumeratedexclamation
End Choose

Return '!'
end function

on eaf_n_cst_conversionservice.create
call super::create
end on

on eaf_n_cst_conversionservice.destroy
call super::destroy
end on